LL412, Interface Midi CV/Gate et plus...

Durant la construction de mon modulaire, j'ai vite ressenti le besoin de développer un module de commande. Je me suis tourné vers la solution Arduino car le produit est vraiment sympa, ouvert, économique, facile à mettre en oeuvre sans PCB. Avec un simple port USB, on reprogramme le plus simplement du monde. L'environnement de développement est libre, convivial , fiable et performant même si il n'y a pas à proprement parler d'outil de deboggage et d'optimisation.

Spécifications du module

• 2 CV (0-5V) (réglage précis de la conversion dans le logiciel) + 2 Gates 
• Midi vers CV suivant la norme 1V/Octave sur cinq octaves (accord fin, transposition)
• Mode Dual et Split
• Gestion de l'expression, vélocité, modulation et bend
• LFO combinable avec modulations, plusieurs formes d'onde
• Gestion du MIDI Clock, Start, Stop etc...
• Arpégiateur (différents motifs, range)
• Mini séquenceur 32 pas.
• Midi Thru, Midi Out
• Interface ergonomique

Plutôt que de longues explications, une petite vidéo ;)

Le schéma

Le DAC et l'optocoupleur sont montés sur une plaque proto pour Arduino comme celle-ci
Mon DAC est un cms, la plaque proto intègre un emplacement pour ce type de composant.

Pour le compilateur, j'utilise et recommande la dernière version dispo à cette adresse : http://arduino.cc/en/Main/Software

Le code source
Le dossier MIDI doit être placé dans libraries. Exemple : C:\arduino-1.0.1\libraries\MIDI
Le fichier LL412.ino peut être placé dans un dossier LL412 de vos documents. C'est lui qu'il faudra ouvrir avec l'environnement de développement Arduino.

La façade est en plexi (PMMA) avec un feuille de SCOTCHMARK pour la sérigraphie...C'est facile à percer et la transparence parfaite évite les découpes pour l'afficheur, car question travail soigneux... ;)

J'ai trouvé l'afficheur pour pas cher sur la baie, celui-ci n'est pas rétro-éclairé . Aussi, tout afficheur type HD44780 2 lignes de 32 ou 40 caractères fera l'affaire. Cela s'adapte en 2 secondes dans le code source.
Une version en 5U avec un 4x20 devrait pouvoir être envisagé en organisant la façade autrement, le code source s'adaptera facilement.

Pour l'alimentation, un bloc secteur pour pédale de guitare (+9 v) fait l'affaire mais il faut inverser la polarité, sur l'Arduino c'est un connecteur 2.1mm avec + au centre.

Quelques photos du b..désordre intérieur et de la façade

et la version 5U de MikZed53

Quelques remarques

L'accord se règle par logiciel. La variable REF_1V donne la correspondance.  Chez moi , c'est 896 pour 1v/octave. Pour régler l'accord, vous pressez A1 et tournez A1 jusqu'à "1 VOLT" et là avec les poussoirs A2 et A3 vous changez la référence pour que la même note soit juste sur au moins 4 octaves. L'utilisation d'un simple accordeur électronique est très pratique pour cela.

Pour l'affichage 2x32, j'ai défini six zones décrites dans le prog, ligne 400:

byte ZL[]= {9, 9, 9, 9, 9, 9};
byte ZPOS[]= {1, 10, 19, 1, 10, 19};
byte ZLIN[]= {0, 0, 0, 1, 1, 1};

ZL est la largeur des zones
ZPOS la colonne de départ
ZLIN la ligne

La zone 1 a une longueur de 9, commence colonne 1 sur la ligne 0
...
La zone 6 a une longueur de 9, commence colonne 19 sur la ligne 1
 
Pour 16 caractères x 2 lignes on peut faire trois zones
xxxxxx xxxx xxxx
xxxxxx xxxx xxxx

ce qui donne 
byte ZL[]= {6, 4, 4, 6, 4, 4};
byte ZPOS[]= {0, 7, 12, 0, 7, 12};
byte ZLIN[]= {0, 0, 0, 1, 1, 1};

Ne pas oublier dans setup()
ligne 1251 :     lcd.begin(32, 2);
devient lcd.begin(16, 2);

Il faudra aussi modifier quelques libellés dans le code qui sont trop longs ;)

Ci-dessous des programmes simplifiées pour tester chaque organe.

Pour le montage, il est plus simple de tester chaque élément avant d'envoyer tout le code. C'est le rôle de ces petits bouts de codes.

L'afficheur

L'afficheur doit afficher Bonjour de LL412

#include <LiquidCrystal.h> 

LiquidCrystal lcd(7, 6, 5, 4, 3, 2);

#define NB_COLONNE 32
#define NB_LIGNE 2

int cpt=0;

void setup()
{
    lcd.begin(NB_COLONNE, NB_LIGNE);
    lcd.clear();
}

void loop()
{

  lcd.setCursor(0,0);
  lcd.print("Bonjour de LL412");
  lcd.setCursor(0,1);
  lcd.print(cpt);
  cpt++;
  delay(1000);
} 

Les gates

Les deux gates doivent battre la seconde...

#include <LiquidCrystal.h>

LiquidCrystal lcd(7, 6, 5, 4, 3, 2);

#define NB_COLONNE 16
#define NB_LIGNE 2

#define GATE_0 8
#define GATE_1 9


int cpt=0;

void setup()
{
    pinMode(GATE_0,OUTPUT);
    pinMode(GATE_1,OUTPUT);

    digitalWrite(GATE_0,LOW);   
    digitalWrite(GATE_1,LOW);   

    lcd.begin(NB_COLONNE, NB_LIGNE);
    lcd.clear();
}

void loop()
{
   lcd.clear();
   lcd.setCursor(0,0);
   lcd.print("Gates On");
   digitalWrite(GATE_0,HIGH);   
   digitalWrite(GATE_1,HIGH);   
   delay(1000);
   lcd.clear();
   lcd.setCursor(0,0);
   lcd.print("Gates Off");
   digitalWrite(GATE_0,LOW);   
   digitalWrite(GATE_1,LOW);   
   delay(1000);
}    

Le midi In

Une note jouée au clavier doit être affichée (appui et relâchement).

#include <LiquidCrystal.h>
#include <MIDI.h>

LiquidCrystal lcd(7, 6, 5, 4, 3, 2);

#define NB_COLONNE 16
#define NB_LIGNE 2

void HandleNoteOn(byte channel, byte pitch, byte velocity)
{
   lcd.clear();
   lcd.setCursor(0,0);
   lcd.print("Note On");
   lcd.setCursor(0,1);
   lcd.print(pitch);
}


void HandleNoteOff(byte channel, byte pitch, byte velocity)
{
   lcd.clear();
   lcd.setCursor(0,0);
   lcd.print("Note Off");
   lcd.setCursor(0,1);
   lcd.print(pitch);
}


void setup()
{
    lcd.begin(NB_COLONNE, NB_LIGNE);
    lcd.clear();

    MIDI.begin(0);  
    MIDI.setHandleNoteOn(HandleNoteOn);
    MIDI.setHandleNoteOff(HandleNoteOff );
}

void loop()
{
    MIDI.read();
}

Un convertisseur Midi CVsimplifié.

Chaque note jouée au clavier sera convertie en tension et gate sur CV 0 et GATE 0

#include <LiquidCrystal.h>
#include <MIDI.h>

LiquidCrystal lcd(7, 6, 5, 4, 3, 2);

#define DATAOUT 11//MOSI
#define DATAIN  12//MISO Pa sutilisé pour le moment
#define SPICLOCK  13//sck
#define DAC_0 10//ss
#define DAC_1 9//ss un seul DAC pour le moment

#define GATE_0 8
#define GATE_1 9

#define NB_COLONNE 16
#define NB_LIGNE 2

int REF_1V = 895; // coorespondance DAC 1v/Oct


void p_CV(byte port, int pitch)
{
    dac_Out(port, (long)REF_1V * pitch / 12  );
}


void HandleNoteOn(byte channel, byte pitch, byte velocity)
{
   lcd.clear();
   lcd.setCursor(0,0);
   lcd.print("Note On");
   lcd.setCursor(0,1);
   lcd.print(pitch);

   p_CV(0, pitch);
   digitalWrite(GATE_0, HIGH);
              

}

void HandleNoteOff(byte channel, byte pitch, byte velocity)
{
   lcd.clear();
   lcd.setCursor(0,0);
   lcd.print("Note Off");
   lcd.setCursor(0,1);
   lcd.print(pitch);
   p_CV(0, pitch);
   digitalWrite(GATE_0, LOW);
}


// ------------------
// Ecriture tension sur DAC
// ------------------

void dac_Out(int port, uint16_t sample)
{

  uint8_t dacSPI0 = 0;
  uint8_t dacSPI1 = 0;
  byte selector;

  switch (port)
  {
  case 0:
      selector = DAC_0;
      sample = sample | 0b0111000000000000;
      break;
  case 1:
      selector = DAC_0;
      sample = sample | 0b1111000000000000;
      break;
  } 
  dacSPI0 = (sample >> 8) & 0x00FF;
  dacSPI1 = sample & 0x00FF;

  digitalWrite(selector,LOW);
  SPDR = dacSPI0;                    // Start the transmission
  while (!(SPSR & (1<<SPIF)))     // Wait the end of the transmission
  {
  };
 
  SPDR = dacSPI1;
  while (!(SPSR & (1<<SPIF)))     // Wait the end of the transmission
  {
  }; 
  digitalWrite(selector,HIGH);

}

// ------------------
// Setup Arduino
// ------------------


void setup()
{
    byte clr;

    lcd.begin(32, 2);
    lcd.clear();

  // Initialisation DAC(s) et SPI
 
    pinMode(GATE_0,OUTPUT);
    pinMode(GATE_1,OUTPUT);

    pinMode(DATAOUT, OUTPUT);
    pinMode(DATAIN, INPUT);
    pinMode(SPICLOCK,OUTPUT);
    pinMode(DAC_0,OUTPUT);
    digitalWrite(DAC_0,LOW);   
   
    SPCR = (1<<SPE)|(1<<MSTR);
    clr=SPSR;
    clr=SPDR;
    delay(10);

    // Initialisation Midi   
    MIDI.begin(0);   
    MIDI.setHandleNoteOn(HandleNoteOn); 
    MIDI.setHandleNoteOff(HandleNoteOff );

    pinMode(GATE_0,OUTPUT);
    pinMode(GATE_1,OUTPUT);

    digitalWrite(GATE_0,LOW);   
    digitalWrite(GATE_1,LOW);   
   

}

void loop()
{
    MIDI.read();
}

@+